simba/t/00_da.t

#!/usr/bin/perl
use warnings;
use strict;

use Test::More tests => 22;

BEGIN { use_ok( 'Simba::DA' ); }

my $da = Simba::DA->new();
ok($da, 'new DA');
$da->log_level(0);	# no log output during tests
my $list;
open(my $fh, '>', \$list);
$da->fh_out($fh);
$da->list('list', 't/root');
close($fh);
ok($list);
cmp_ok($list, '=~', qr{^\. .* t=d }m, 'root is a directory');
cmp_ok($list, '=~', qr{^\./test.txt .* t=f s=14 }m, 'text file found');
cmp_ok($list, '=~', qr{^\./test.bin .* t=f s=1024 }m, 'binary file found');
cmp_ok($list, '=~', qr{^\./test.link .* t=l .* lt=test.bin( |$)}m, 'symlink found');
cmp_ok($list, '=~', qr{^\./ABAecom_=sub.__Am._Bankers_Assn.=_Root_CA.pem .* t=l .* lt=/usr/share/ca-certificates/mozilla/ABAecom_=sub.__Am._Bankers_Assn.=_Root_CA.crt( |$)}m, 'symlink found');

my $result;
open($fh, '>', \$result);
$da->fh_out($fh);
$da->get('get', './test.txt');
ok($result, 'get returned something');

my ($header, $content, $trailer);
if ($result =~ /\A ([^\n]*) \n (.*) \n ([^\n]*) \n \z/xs) {
    ($header, $content, $trailer) = ($1, $2, $3);
}

ok($header, 'header found');
cmp_ok($header, '=~', qr{./test.txt .* t=f s=14 }, 'text file found');

ok($content, 'content found');
cmp_ok(length($content), '==', 14, 'text file is 14 bytes long');

ok($trailer, 'trailer found');
is($trailer, 'chk sha1 e3b9312f5f7afbe0bfff5c49ab5e9a160b2b04f4', 'trailer contains correct checksum');

open($fh, '>', \$result);
$da->fh_out($fh);
$da->get('get', './test.bin');

($header, $content, $trailer)
    = $result =~ /\A ([^\n]*) \n (.*) \n ([^\n]*) \n \z/xs;

ok($header, 'header found');
cmp_ok($header, '=~', qr{./test.bin .* t=f s=1024 }, 'binary file found');

ok($content, 'content found');

cmp_ok(length($content), '==', 1024, 'binary file is 1024 bytes long');

ok($trailer, 'trailer found');
is($trailer, 'chk sha1 97253f25fc3945cd6293e3dfad2a322041b14164', 'trailer contains correct checksum');

open($fh, '>', \$result);
$da->fh_out($fh);
$da->no_such_command('no_such_command');
cmp_ok(length($result), '>', 0, 'invoking nonexistant command produces message');