124 lines
1.7 KiB
POVRay
124 lines
1.7 KiB
POVRay
|
|
#declare hangar_neg =
|
|
difference {
|
|
cone {
|
|
<0, 0, 0>, 900,
|
|
<0, 115, 0>, 900
|
|
}
|
|
cone {
|
|
<0, 0, 0>, 900-140,
|
|
<0, 115, 0>, 900-140
|
|
}
|
|
}
|
|
|
|
#declare triebwerk_neg =
|
|
difference {
|
|
cone {
|
|
<0, 599, 0>, 900,
|
|
<0, 501, 0>, 900
|
|
}
|
|
cone {
|
|
<0, 599, 0>, 600,
|
|
<0, 501, 0>, 600
|
|
}
|
|
}
|
|
|
|
#declare landestuetzen_neg =
|
|
union {
|
|
#declare i = 0;
|
|
#while (i < 16)
|
|
cone {
|
|
<350, -700, 0>, 25,
|
|
<350, -900, 0>, 25
|
|
rotate <0, i*360/16, 0>
|
|
}
|
|
#declare i = i + 1;
|
|
#end
|
|
}
|
|
|
|
#include "kombiblock.pov"
|
|
#include "metagrav.pov"
|
|
#include "vesta.pov"
|
|
|
|
#declare Strut_Ext = 11/15;
|
|
#include "strut.pov"
|
|
|
|
#declare entdecker =
|
|
union {
|
|
difference {
|
|
sphere {
|
|
<0, 0, 0>, 900
|
|
}
|
|
object {
|
|
hangar_neg
|
|
translate <0, 10, 0>
|
|
}
|
|
object {
|
|
hangar_neg
|
|
translate <0, -10-115, 0>
|
|
}
|
|
object {
|
|
triebwerk_neg
|
|
}
|
|
object {
|
|
triebwerk_neg
|
|
scale <1, -1, 1>
|
|
}
|
|
object {
|
|
landestuetzen_neg
|
|
}
|
|
texture {Ynkelonium_Texture }
|
|
}
|
|
|
|
#declare i = 0;
|
|
#while (i < 360)
|
|
#declare j = -1;
|
|
#while (j <= +1)
|
|
object {
|
|
kombiblock_oben
|
|
rotate <0, i + 20*j, 0>
|
|
translate <0, 500, 0>
|
|
}
|
|
#declare j = j + 1;
|
|
#end
|
|
|
|
object {
|
|
metagrav
|
|
translate <-740, 501, 0>
|
|
rotate <0, i + 45, 0>
|
|
}
|
|
|
|
#declare i = i + 90;
|
|
#end
|
|
|
|
#declare i = 0;
|
|
#while (i < 360)
|
|
|
|
object {
|
|
vesta
|
|
translate <830, 50+10, 0>
|
|
rotate <0, i, 0>
|
|
}
|
|
|
|
object {
|
|
vesta
|
|
translate <830, 50-115-10, 0>
|
|
rotate <0, i, 0>
|
|
}
|
|
|
|
#declare i = i + 12;
|
|
#end
|
|
|
|
#declare i = 0;
|
|
#while (i < 16)
|
|
object {
|
|
strut
|
|
translate <350, -900, 0>
|
|
rotate <0, i*360/16, 0>
|
|
}
|
|
#declare i = i + 1;
|
|
#end
|
|
}
|
|
|
|
|