3d/pr/schneller_kreuzer/ein-mann-jaeger.pov

#include "T_arkonstahl.pov"

#declare ein_mann_jaeger_tf_r =
    union {
	triangle {
	    <0.6, 1.0, 1.6> <5.0, 1.0, 3.0> <0.5, 1.1, 8.0>
	}
	triangle {
	    <0.6, 1.0, 9.0> <5.0, 1.0, 3.0> <0.5, 1.1, 8.0>
	}
	triangle {
	    <0.6, 1.0, 1.6> <5.0, 1.0, 3.0> <0.5, 1.0, 9.0>
	}
	cylinder {
	    <2.0, 1.0, 1.9> <2.0, 1.0, 7.4> 0.2
	}
	difference {
	    cone {
		<2.0, 1.0, 1.6> 0.1
		<2.0, 1.0, 1.9> 0.2
	    }
	    cone {
		<2.0, 1.0, 1.5> 0.08
		<2.0, 1.0, 1.9> 0.05
		pigment { color rgb 0.2 }
	    }
	}
	difference {
	    cone {
		<2.0, 1.0, 7.7> 0.1
		<2.0, 1.0, 7.4> 0.2
	    }
	    cone {
		<2.0, 1.0, 7.8> 0.08
		<2.0, 1.0, 7.4> 0.05
		pigment { color rgb 0.2 }
	    }
	}
    }

#declare ein_mann_jaeger_kufe_r =
    union {
	cylinder {
	    <0, -0.5, 2>
	    <0, -0.5, 8>
	    0.5
	}
	sphere {
	    <0, 0, 0> 1
	    scale <0.5, 0.5, 1>
	    translate <0, -0.5, 2>
	}
	sphere {
	    <0, 0, 0> 1
	    scale <0.5, 0.5, 1>
	    translate <0, -0.5, 8>
	}
	scale <0.5, 1/cos(radians(30)), 1>
	rotate <0, 0, 30>
	translate <0, +1, 0>
    }

#local r1 = 0.3;
#declare ein_mann_jaeger = 
    union {

	// Hecktriebwerk:

	#local ii = 0;
	#while (ii < 1.1) 
	    intersection {
		torus {
		    1-r1, r1
		    rotate <90, 0, 0>
		}
		box { 
		    <-1, 0, -r1>
		    <+1, 1, +r1>
		}
		scale <0.4 + 0.2 * ii, 0.4 + 0.6 * ii, 0.2/r1>
		translate <0, 1.2 - 0.2 * ii, 0.2 + ii>
	    }
	    intersection {
		torus {
		    1-r1, r1
		    rotate <90, 0, 0>
		}
		box { 
		    <-1, 0, -r1>
		    <+1, -1, +r1>
		}
		scale <0.4 + 0.2 * ii, 0.4 + 0.2 * ii, 0.2/r1>
		translate <0, 1.2 - 0.2 * ii, 0.2 + ii>
	    }
	    #local ii = ii + 0.2;
	#end

	// Rumpf

	intersection {
	    cylinder {
		<0, 0, 0> <0, 0, 1> 1
	    }
	    box { 
		<-1, 0, 0>
		<+1, 1, 1>
	    }
	    scale <0.6, 1, 9.6-1.2>
	    translate <0, 1, 1.2>
	}

	intersection {
	    cylinder {
		<0, 0, 0> <0, 0, 1> 1
	    }
	    box { 
		<-1, 0, 0>
		<+1, -1, 1>
	    }
	    scale <0.6, 0.6, 9.6-1.2>
	    translate <0, 1, 1.2>
	}

	// Schnauze

	intersection {
	    sphere {
		<0, 0, 0> 1
	    }
	    box { 
		<-1, 0, 0>
		<+1, 1, 1>
	    }
	    scale <0.6, 1, 4.06>
	    translate <0, 1, 9.6>
	}

	intersection {
	    sphere {
		<0, 0, 0> 1
	    }
	    box { 
		<-1, 0, 0>
		<+1, -1, 1>
	    }
	    scale <0.6, 0.6, 4.06>
	    translate <0, 1, 9.6>
	}


	// Impulskanone

	difference {
	    cone {
		<0, 1, 13.5> 0.2
		<0, 1, 15> 0.1
	    }
	    cone {
		<0, 1, 13.5> 0.05
		<0, 1, 15.01> 0.08
	    }
	}

	// Pilotenkuppel

	bicubic_patch {
	    type 0
	    u_steps 3
	    v_steps 3
	    <+0.4, 1.70, 10.2> <+0.4, 1.65, 10.7> <+0.4, 1.55, 11.2> <+0.4, 1.45, 11.7>
	    <+0.2, 1.95,  9.6> <+0.2, 2.8,  10.2> <+0.2, 2.5,  11.5> <+0.2, 1.55, 12.1>
	    <-0.2, 1.95,  9.6> <-0.2, 2.8,  10.2> <-0.2, 2.5,  11.5> <-0.2, 1.55, 12.1>
	    <-0.4, 1.70, 10.2> <-0.4, 1.65, 10.7> <-0.4, 1.55, 11.2> <-0.4, 1.45, 11.7>

	    texture {
	      pigment { color red 0.3 green 0.3 blue 0.1}
	      finish {
		ambient 0.0
		diffuse 0.1
		brilliance 1
		reflection 0.2
		specular 0.5
		roughness 0.001
	      }
	    } 
	    
	}

	// leitwerk

	triangle {
	    <0, 2, 1.2> <0, 4.4, 1.0> <0.1, 1.9, 3.9>
	}
	triangle {
	    <0, 4.4, 1.0> <0.1, 1.9, 3.9> <0, 2, 4.4>
	}
	triangle {
	    <0, 2, 1.2> <0, 4.4, 1.0> <-0.1, 1.9, 3.9>
	}
	triangle {
	    <0, 4.4, 1.0> <-0.1, 1.9, 3.9> <0, 2, 4.4>
	}


	// Tragfl<66>chen

	object {
	    ein_mann_jaeger_tf_r 
	}
	object {
	    ein_mann_jaeger_tf_r 
	    scale <-1, 1, 1>
	}


	// Landekufen 

	object {
	    ein_mann_jaeger_kufe_r 
	}
	object {
	    ein_mann_jaeger_kufe_r 
	    scale <-1, 1, 1>
	}


	texture { T_arkonstahl }
    }