#include "metals.inc"

// Distanz der Schrägflächen vom Mittelpunkt
#declare d = sqrt(pow(((1 + 2 * sqrt(0.5)) / 3), 2) * 3);

#declare oktaeder =
    intersection {
	plane {
	    <1, 1, 1>, d
	}
	plane {
	    <1, 1, -1>, d
	}
	plane {
	    <1, -1, 1>, d
	}
	plane {
	    <1, -1, -1>, d
	}
	plane {
	    <-1, 1, 1>, d
	}
	plane {
	    <-1, 1, -1>, d
	}
	plane {
	    <-1, -1, 1>, d
	}
	plane {
	    <-1, -1, -1>, d
	}
    }
	
#declare ziffernblatt =
    union {
	cylinder {
	    <0.99, 0, 0>, <0.98, 0, 0> 0.86
	    texture {
		pigment {
		    color <1, 1, 1, 0.0>
		}
		//normal {granite 0.4 scale 0.000001}
		finish {
		    ambient 2
		}
	    }
	    interior {
		ior 1.5
	    }
	}
	#local m = 0;
	#while (m < 60)
	    #if (mod(m, 15) = 0)
		prism {
		    linear_spline linear_sweep
		    0.99, 1.00,
		    5,
		    <-0.84, 0.00>,
		    <-0.64, 0.05>,
		    <-0.59, 0.00>,
		    <-0.64, -0.05>
		    <-0.84, 0.00>
		    rotate <0, 0, -90>
		    rotate <m * 6, 0, 0>
		}
	    #else 
	    #if (mod(m, 5) = 0)
		prism {
		    linear_spline linear_sweep
		    0.99, 1.00,
		    5,
		    <-0.84, 0.00>,
		    <-0.70, 0.03>,
		    <-0.67, 0.00>,
		    <-0.70, -0.03>
		    <-0.84, 0.00>
		    rotate <0, 0, -90>
		    rotate <m * 6, 0, 0>
		}
	    #else 
		cylinder {
		    <0.99, 0.82, 0>, <1.00, 0.82, 0>, 0.02
		    rotate <m * 6, 0, 0>
		}
	    #end
	    #end
	    #local m = m + 1;
	#end

	prism {
	    linear_spline linear_sweep
	    1.01, 1.02,
	    13,
	    <-0.84, 0.00>,
	    <-0.60, 0.07>,
	    <-0.03, 0.03>,
	    <+0.00, 0.04>,
	    <+0.03, 0.03>,
	    <+0.20, 0.05>
	    <+0.30, 0.00>
	    <+0.20, -0.05>
	    <+0.03, -0.03>,
	    <+0.00, -0.04>,
	    <-0.03, -0.03>,
	    <-0.60, -0.07>,
	    <-0.84, 0.00>
	    rotate <0, 0, -90>
	    rotate <minute * 6, 0, 0>
	}

	prism {
	    linear_spline linear_sweep
	    1.00, 1.01,
	    8,
	    <-0.60, 0.00>,
	    <-0.35, 0.10>,
	    <-0.00, 0.04>,
	    <+0.15, 0.06>
	    <+0.15, -0.06>
	    <-0.00, -0.04>,
	    <-0.35, -0.10>,
	    <-0.60, 0.00>
	    rotate <0, 0, -90>
	    rotate <(stunde + minute / 60) * 30, 0, 0>
	}

    }

#declare wuerfeluhr = 
    union {
	difference {
	    union {
		intersection {
		    box {
			<-1, -1, -1>, <1, 1, 1>
		    }
		    object {
			oktaeder
		    }
		    texture {
			pigment {
			    color <0.8, 0.8, 0.8>
			}
			finish {
			    F_MetalA
			    reflection 0.05
			}
			//normal {granite 0.4 scale 0.000001}
		    }
		}
		cylinder {
		    <-1.02, 0, 0>, <1.02, 0, 0>, 0.93
		    texture {
			pigment {
			    color <0.9, 0.9, 0.9>
			}
			finish {
			    F_MetalA
			    reflection 0.05
			}
		    }
		}
		cylinder {
		    <0, 0, -1.02>, <0, 0, 1.02>, 0.93
		    texture {
			pigment {
			    color <0.9, 0.9, 0.9>
			}
			finish {
			    F_MetalA
			    reflection 0.05
			}
		    }
		}
	    }
	    cylinder {
		<-2, 0, 0>, <2, 0, 0>, 0.86
		texture {
		    pigment {
			color <0.8, 0.8, 0.8>
		    }
		}
	    }
	    cylinder {
		<0, 0, -2>, <0, 0, 2>, 0.86
		texture {
		    pigment {
			color <0.8, 0.8, 0.8>
		    }
		}
	    }
	}
	object {
	    ziffernblatt
	}
	object {
	    ziffernblatt
	    rotate <0, 90, 0>
	}
	object {
	    ziffernblatt
	    rotate <0, 180, 0>
	}
	object {
	    ziffernblatt
	    rotate <0, 270, 0>
	}
//	sphere {
//	    <0, 0, 0>, 0.1
//	    texture {
//		pigment {
//		    color <1, 1, 1>
//		}
//		finish {
//		    ambient 100
//		}
//	    }
//	}
    }