#include "T_arkonstahl.pov"
#include "glass.inc"

#declare gummi =
    texture {
	pigment {
	    color 0.2
	    
	}
    }

#declare trafo = 
    union {
	intersection {
	    sphere {
		0, 1
		scale <1.1, 4, 1.1>
	    }
	    box {
		<-1, 0, -1>
		<1, 4, 1>
	    }
	    texture { T_arkonstahl }
	}
	intersection {
	    sphere {
		0, 1
		scale <1.1, 2, 1.1>
		texture { T_Copper_3D }
	    }
	    box {
		<-1, 1.2, -1>
		<1, 2, 1>
	    }
	    translate <0, 2.3, 0>
	}
	intersection {
	    sphere {
		0, 1
		scale <1.1, 2, 1.1>
		texture { T_Copper_3D }
	    }
	    box {
		<-1, 1.4, -1>
		<1, 2, 1>
	    }
	    translate <0, 2.6, 0>
	}
	intersection {
	    sphere {
		0, 1
		scale <1.1, 2, 1.1>
		texture { T_Copper_3D }
	    }
	    box {
		<-1, 1.6, -1>
		<1, 2, 1>
	    }
	    translate <0, 2.9, 0>
	}
    }

#declare speicherbank = 
    union {
	box {
	    <1, 0, -2.5>
	    <8, 8,  2.5>
	    texture {pigment {color White }}
	}
	box {
	    <0, 0, -2.5>
	    <1, 4,  1.5>
	    texture {pigment {color White }}
	}
	#local i = 0.1;
	#while (i < 4) 
	    cylinder {
		<0.25, i, 1.6>
		<0.75, i, 1.6>
		0.02
		texture { gummi }
	    }
	    #local i = i + 0.2;
	#end
	cylinder {
		<0.25, 0, 1.6>
		<0.25, 5, 1.6>
		0.02
		texture { gummi }
	}
	cylinder {
		<0.75, 0, 1.6>
		<0.75, 5, 1.6>
		0.02
		texture { gummi }
	}
	cylinder {
		<0.75, 5, 1.6>
		<0.75, 5, 1.45>
		0.02
		texture { gummi }
	}
	cylinder {
		<0.75, 5, 1.45>
		<1,    5, 1.45>
		0.02
		texture { gummi }
	}
	cylinder {
		<0.25, 5, 1.6>
		<0.25, 5, 1.45>
		0.02
		texture { gummi }
	}
	cylinder {
		<0.25, 5, 1.45>
		<0.05, 5, 1.45>
		0.02
		texture { gummi }
	}
	cylinder {
		<0.05, 5, 1.45>
		<0.05, 5, -2.45>
		0.02
		texture { gummi }
	}
	cylinder {
		<0.05, 5, -2.45>
		<1.00, 5, -2.45>
		0.02
		texture { gummi }
	}
	#local i = 0;
	#while (i <= 4) 
	    cylinder {
		<0.05, 5, i * (2.45 + 1.45) / 4 - 2.45 >
		<0.05, 4, i * (2.45 + 1.45) / 4 - 2.45 >
		0.02
		texture { gummi }
	    }
	    #local i = i + 1;
	#end
	union {
	    box {
		<0, 0, 0>, <1.4, 0.9, -0.01>
		texture {
		    pigment {Black}
		}
	    }
	    box {
		<0.4, 0.5, 0.01>, <1.3, 0.8, -0.02>
		texture {
		    pigment {Green}
		}
	    }
	    sphere {
		<0.55, 0.35, 0.01>, 0.13
		scale <1, 1, 0.1>
		texture {
		    pigment {Green}
		}
	    }
	    sphere {
		<0.85, 0.35, 0.01>, 0.13
		scale <1, 1, 0.1>
		texture {
		    pigment {Yellow}
		}
	    }
	    sphere {
		<1.15, 0.35, 0.01>, 0.13
		scale <1, 1, 0.1>
		texture {
		    pigment {Red}
		}
	    }
	    matrix <		// swap x<->z		// swap x<->z
		0, 0, 1,
		0, 1, 0,
		1, 0, 0,
		0, 0, 0
	    >
	    translate <1, 5, -1.4>
	}
	object {
	    trafo
	    translate <7, 0, -3.5>
	}
	object {
	    trafo
	    translate <7, 0, +3.5>
	}
	torus {
	    1, 0.5
	    rotate <90, 0, 0>
	    translate <5, 5, -2.5>
	    texture { T_Copper_3D }
	}
	torus {
	    1, 0.5
	    rotate <90, 0, 0>
	    translate <5, 5, +2.5>
	    texture { T_Copper_3D }
	}
	intersection {
	    torus {
		5, 1
		
	    }
	    plane { 
		<-1, 0, 0> 0
		rotate <0, 0, 0>
	    }
	    plane { 
		<0, 0, -1> 0
		rotate <0, 0, 0>
	    }
	    plane { 
		<0, 0, +1> 0
		rotate <0, -60, 0>
	    }
	    texture {
		T_Ruby_Glass
	    }
	    interior {
		ior 1.1
	    }
	    translate <0, 5, 5 * sqrt(1/3)>
	}
    }