#declare eps=1E-3;

#declare bett = 
    box {
	<0, 0.2, 0>
	<2, 0.4, 1>
	texture {
	    pigment {
		color <1.0, 1.0, 0.8>
	    }
	}
    }
#declare kasten =
    box {
	<0, 0.0, 0>
	<1.5, 2.0, 0.6>
	texture {
	    pigment {
		color <0.8, 1.0, 0.8>
	    }
	}
    }

#declare klo =
    intersection {
	difference {
	    sphere {
		0, 1
		scale <0.22, 0.4, 0.2>
	    }
	    sphere {
		0, 1
		scale <0.17, 0.2, 0.16>
	    }
	    translate <0, 0.4, 0>
	}
	box {
	    <-0.22, 0,  -0.2>
	    <+0.22, 0.4, 0.2>
	}
	texture {
	    pigment {
		color <1.0, 1.0, 1.0>
	    }
	}
    }

#declare tisch =
    union {
	cylinder {
	    <0, 0.68, 0>
	    <0, 0.70, 0>
	    0.5
	}
	cylinder {
	    <0, 0.68, 0>
	    <0, 0.00, 0>
	    0.05
	}
	texture {
	    pigment {
		color <0.4, 0.4, 0.2>
	    }
	}
    }

#declare stuhl = 
    union {
	box {
	    <-0.2, 0.38, -0.2>
	    <+0.2, 0.38, +0.2>
	}
	box {
	    <+0.3, 0.38, -0.2>
	    <+0.3, 0.80, +0.2>
	}
	cylinder {
	    <-0.19, 0, -0.19>, 
	    <-0.19, 0.38, -0.19>, 
	    0.01
	}
	cylinder {
	    <-0.19, 0, +0.19>, 
	    <-0.19, 0.38, +0.19>, 
	    0.01
	}
	cylinder {
	    <+0.19, 0, +0.19>, 
	    <+0.19, 0.38, +0.19>, 
	    0.01
	}
	cylinder {
	    <+0.19, 0, -0.19>, 
	    <+0.19, 0.38, -0.19>, 
	    0.01
	}
	texture {
	    pigment {
		color <0.4, 0.4, 0.2>
	    }
	}
    }

#declare duschwanne =
    difference {
	box {
	    <-0.4, 0,  -0.4>
	    <+0.4, 0.2, 0.4>
	}
	superellipsoid {
	    <0.1, 0.1>
	    scale <0.35, 0.15, 0.35>
	    translate <0, 0.2, 0>
	}
	texture {
	    pigment {
		color <1.0, 1.0, 1.0>
	    }
	}
    }

#declare waschbecken = 
    difference {
	box {
	    <-0.2, 0,  -0.3>
	    <+0.2, 0.3, 0.3>
	}
	superellipsoid {
	    <0.1, 0.1>
	    scale <0.14, 0.25, 0.28>
	    translate <-0.04, 0.3, 0>
	}
	translate <-0.2, 0.7, 0>
	texture {
	    pigment {
		color <1.0, 1.0, 1.0>
	    }
	}
    }


#declare kabine1 = 
    union {
	intersection {
	    union {
		difference {
		    cylinder {
			<0, 0, 0>
			<0, 5, 0>
			6.1
		    }
		    cylinder {
			<0, 0-eps, 0>
			<0, 5+eps, 0>
			6.0
		    }
		}
		difference {
		    cylinder {
			<0, 0, 0>
			<0, 5, 0>
			10.0
		    }
		    cylinder {
			<0, 0-eps, 0>
			<0, 5+eps, 0>
			9.9
		    }
		}
	    }
	    plane {
		<-1, 0, 0>,
		-1
	    }
	    plane {
		<+1, 0, 0>
		0
		rotate <0, +45, 0>
	    }
	    plane {
		<0, 0, -1>
		0
	    }
	}
	box {
	    <6.0, 0, -0.05>
	    <10.0, 5, 0.05>
	    rotate <0, -45, 0>
	}
	box {
	    <1.0, 0, sqrt(35)>
	    <1.1, 5, sqrt(99)>
	}
	object {
	    bett
	    translate <7.8, 0, 0.1>
	    rotate <0, -45, 0>
	}
	object {
	    kasten
	    translate <6.2, 0, 0.05>
	    rotate <0, -45, 0>
	}

	object {
	    duschwanne
	    translate <1.4, 0, 9.5>
	}

	object {
	    waschbecken
	    rotate <0, -180, 0>
	    translate <1.0, 0, 8.5>
	}

	object {
	    klo
	    rotate <0, -180, 0>
	    translate <1.3, 0, 8.0>
	}

	box {
	    <1, 0, 7.5>
	    <2, 5, 7.51>
	    texture {
		pigment { color White }
	    }
	}

	box {
	    <2, 0, 7.5>
	    <2.01, 5, sqrt(10*10-2*2)>
	    texture {
		pigment { color White }
	    }
	}

	union {
	    object {
		tisch 
	    }
	    object {
		stuhl
		translate <0.5, 0, 0>
		rotate <0, 0, 0>
	    }
	    object {
		stuhl
		translate <0.5, 0, 0>
		rotate <0, 120, 0>
	    }
	    object {
		stuhl
		translate <0.5, 0, 0>
		rotate <0, 240, 0>
	    }
	    translate <4, 0, 7>
	}


	texture {
	    pigment {
		color <0.8, 1.0, 0.8>
	    }
	}
    }