#include "metals.inc"
#local r1 = 41.0;

#declare feldschirm_projektor_v = 
    union {
	intersection {
	    union {
		difference {
		    sphere {
			<0, 0, 0>, r1
		    }
		    sphere {
			<0, 0, 0>, r1-0.5
		    }
		}
		difference {
		    sphere {
			<0, 0, 0>, r1-1.0
		    }
		    sphere {
			<0, 0, 0>, r1-1.5
		    }
		}
		difference {
		    sphere {
			<0, 0, 0>, r1-2.0
		    }
		    sphere {
			<0, 0, 0>, r1-2.5
		    }
		}
		texture { pigment { rgb < 0.2, 0.2, 0.4 > } }
	    }
	    cone {
		<0,0,0>, 0
		<0, -50, 0>, 5
		scale <0.5, 1, 1>
		rotate <0, 0, 18>
		texture { pigment { rgb < 0.2, 0.2, 0.2 > } }
	    }
	}
	intersection {
	    cone {
		<0,0,0>, 0
		<0, -50, 0>, 1
		scale <1, 1, 0.5>
		rotate <0, 0, 18>
		texture { pigment { rgb < 1.2, 0.2, 0.2 > } }
	    }
	    cone {
		<0, -35.2, 0>, 15,
		<0, -39.8, 0>, 15
	    }
	}

	#local fsp_t = r1 - 3.2;
	cone {
	    <-4, -fsp_t, 0>, fsp_t/50 * 0.5
	    < 0, -fsp_t, 0>, fsp_t/50 * 0.5
	    scale <1, 1, 1>
	    rotate <0, 0, 18>
	    texture { pigment { rgb < 1.2, 0.2, 0.2 > } }
	}

	#local fsp_x  = 9.0;
	#local fsp_y  = -40;
	sphere {
	    <(fsp_x-0.5), (fsp_y+3.8), 0>, 1
	    texture { T_Copper_3D }
	}
	cone {
	    <-0, 3.6, 0>, 1
	    <-0, 0, 0>, 1.5
	    matrix <
		1,        0, 0,
		-0.5/3.6, 1, 0,
		0,        0, 1,
		0,        0, 0
	    >

	    translate <fsp_x, (fsp_y+0.2), 0>
	    texture { pigment { rgb < 1, 0.9, 1 > } }
	}
	cone {
	    <(fsp_x-0.5), (fsp_y+2), -3>, 0.5
	    <(fsp_x-0.5), (fsp_y+2), +3>, 0.5
	    texture { pigment { rgb < 1, 0.8, 1 > } }
	}
	sphere {
	    <(fsp_x-0.5), (fsp_y+2), -3>, 0.6
	    texture { T_Copper_3D }
	}
	sphere {
	    <(fsp_x-0.5), (fsp_y+2), +3>, 0.6
	    texture { T_Copper_3D }
	}
    }