/*
    Ortungszentrale

 */
#local H = 5;	// deckhoehe
#local Eps = 1E-6;

#include "hufeisenpult.pov"
#include "rounded_box.pov"



#declare tuer_neg = 
    object {
	rounded_box(<5, 0, -1>, <7, 3, 1>, 0.2)
    }

#declare hufeisenpult_ortung =
    union {
	object {
	    hufeisenpult
	}
	union {
	    union {
		rounded_box(<0, -0.2, -0.3>, <0.1, +0.2, +0.3>, 0.02)
		pigment { color 0.5 }
	    }
	    union {
		rounded_box(<-0.02, -0.18, -0.28>, <0.03, +0.18, +0.28>, 0.02)
		pigment { color 0.1 }
	    }
	    rotate <0, 0, -30>
	    translate <0.9, 1.0, 0>
	}
	union {
	    union {
		rounded_box(<0, -0.2, -0.2>, <0.1, +0.2, +0.2>, 0.02)
		pigment { color 0.5 }
	    }
	    union {
		rounded_box(<-0.02, -0.18, -0.18>, <0.03, +0.18, +0.18>, 0.02)
		pigment { color 0.1 }
	    }
	    rotate <0, 0, -30>
	    translate <0.9, 1.0, 0>
	    rotate <0, 35, 0>
	}
	union {
	    union {
		rounded_box(<0, -0.2, -0.2>, <0.1, +0.2, +0.2>, 0.02)
		pigment { color 0.5 }
	    }
	    union {
		rounded_box(<-0.02, -0.18, -0.18>, <0.03, +0.18, +0.18>, 0.02)
		pigment { color 0.1 }
	    }
	    rotate <0, 0, -30>
	    translate <0.9, 1.0, 0>
	    rotate <0, -35, 0>
	}
    }
#declare ortungs_zentrale = 
    union {
	difference {
	    cylinder {
		<0, 0, 0>, <0, 5, 0>, 6
	    }
	    cylinder {
		<0, 0-Eps, 0>, <0, 4+Eps, 0>, 5.7
	    }
	    cone {
		<0, 4, 0>, 5.7
		<0, H, 0>, 5
	    }
	    object {
		tuer_neg
	    }
	    object {
		tuer_neg
		rotate <0, 180, 0>
	    }
	    object {
		tuer_neg
		rotate <0, 270, 0>
	    }
	    #if (SCHNITT_1) 
	    cylinder {
		<0, 0, 0>
		<0, 5+Eps, 0>
		5
	    }
	    #end
	}
	#local I = 0;
	#while (I < 360)
	    object {
		hufeisenpult_ortung
		translate <-4.5, 0, 0>
		rotate <0, I, 0>
	    }
	    #local I = I + 30;
	#end

	texture { T_arkonstahl }
    }