#include "treibstofftank.pov"
#include "landestuetze.pov"

#declare deck_03 = 
    union {
	#if (1)
	intersection {
	    union {
		difference {
		    object { huelle }
		    // Ausschnitte
		    #local i = 0;
		    #while (i < 12) 
			object { 
			    landestuetze_neg
			    rotate <0, i * 30, 0>
			}
			#local i = i + 1;
		    #end
		}
	    }
	    box {
		< 50, -40,  50>
		<-50, -35, -50>
	    }
	}
	#end
	difference {
	    cone {
		<0, -40.2, 0> 29.5
		<0, -39.8, 0> 30.0
		texture { T_arkonstahl }
	    }
	    // AG
	    cylinder {
		<0, -39, 0> <0, -41, 0> 2
	    }
	    #ifdef (SCHNITT_1)
	    intersection {
		torus {
		    28, 13
		}
		plane { 
		    <0, 0, -1> 0
		    rotate <0, 45, 0>
		}
		plane { 
		    <0, 0, +1> 0
		    rotate <0, -45, 0>
		}
		rotate <0, 135, 0>
		translate <0, -40.0, 0>
	    }
	    #end
	}
        #local rr = 15.5;
	#while (rr < 27.2) 
	    #local da = degrees(asin(0.5/rr))*2;
	    #local aa = 0;
	    #while (aa <= 360 - da) 
		#local ss = 1;
		#ifdef (SCHNITT_1)
		    #local pp = vrotate(<rr, 0, 0>, <0, aa, 0>);
		    #if (pp.x < 0 & pp.z < 0) 
			#local ss = 0;
		    #end
		#end
		#if (ss) 
		    object {
			treibstofftank
			translate <rr, -39.8, 0>
			rotate <0, aa, 0>
		    }
		#end
		#local aa = aa + da;
	    #end
	    #local rr = rr + 1.0;
	#end
    }