hjp
/
3d
1
0
Fork 0
Code Issues Pull Requests Projects Releases Wiki Activity

*** empty log message ***

This commit is contained in:
hjp 1998-03-05 22:41:45 +00:00
parent 170afff3be
commit 5312a45af2
18 changed files with 1172 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

57
pr/star/Hangar_Schotts.pov Normal file
View File

@ -0,0 +1,57 @@
#include "ynkelonium_texture.pov"
#declare Hangar_Schotts =
intersection {
difference {
sphere {
<0,0,0>, 99
}
sphere {
<0,0,0>, 98
}
}
union {
// obere Hangars
#declare i = 0
#while (i < 360)
difference {
superellipsoid {
<0.25, 0.25>
scale <17, 8.5, 25>
}
box {
<-0.1, -8.5, -25>
<+0.1, +8.5, +25>
}
translate <0, 41.5, 80>
rotate <0, i, 0>
}
#declare i = i + 45
#end
// untere Hangars
#declare i = 0
#while (i < 360)
difference {
superellipsoid {
<0.25, 0.25>
scale <10, 5, 25>
}
box {
<-10, -0.1, -25>
<+10, +0.1, +25>
}
translate <0, -64, 65>
rotate <0, i, 0>
}
#declare i = i + 45
#end
}
texture { Ynkelonium_Texture }
}

108
pr/star/Hyperfunk.pov Normal file
View File

@ -0,0 +1,108 @@
#declare Hyperfunk_1 =
union {
sphere {
<0, 8, 0>, 2
texture { T_Chrome_2B }
normal {
dents 1
scale 0.3
}
}
sor {
11,
<3.0, -0.1>,
<3.5, 0>,
<3.0, 1>,
<1.5, 1.001>,
<1.3, 1.2>,
<1.2, 2>,
<1.1, 4>,
<0.8, 5>,
<1, 6>,
<1.3, 7>,
<1.5, 8>
}
sphere {
<2.25, 2, 0>, 0.75
}
cone {
<2.25, 2, 0>, 0.75
<2.25, 1, 0>, 0.75
}
texture { T_Chrome_2B }
}
#declare Hyperfunk_2 =
union {
union {
union {
sphere {
<0, 0, 0>, 0.5
}
cone {
<0, 0, 0>, 0.5,
<1, 0, 0>, 0.5
}
sphere {
<2, 0, 0>, 0.5
}
texture { T_Chrome_2B }
}
union {
cone {
<2, 0, 0>, 0.4,
<1, 0, 0>, 0.4
}
torus {
0.5, 0.1
rotate <0, 0, 90>
translate <1.2, 0, 0>
}
torus {
0.5, 0.1
rotate <0, 0, 90>
translate <1.4, 0, 0>
}
torus {
0.5, 0.1
rotate <0, 0, 90>
translate <1.6, 0, 0>
}
torus {
0.5, 0.1
rotate <0, 0, 90>
translate <1.8, 0, 0>
}
cone {
<2, 0, 0>, 0.1,
<4, 0, 0>, 0.0
}
texture { T_BlackMetal }
}
rotate <0, 0, 45>
translate <2, 0, 0>
}
cone {
<0, 0, 0>, 1
<2, 0, 0>, 0.5
scale <1, 1, 0.1>
texture { T_BlackMetal }
}
}
#declare Hyperfunk =
union {
object {Hyperfunk_1}
object {
Hyperfunk_2
translate <0, 6, 0>
rotate <0, 45, 0>
}
object {
Hyperfunk_2
translate <0, 6, 0>
rotate <0, 225, 0>
}
}

73
pr/star/Hypertrop.pov Normal file
View File

@ -0,0 +1,73 @@
#include "T_BlackMetal.pov"
#declare Hypertrop_Projektor_Aussen =
sor {
4,
<21, -8>
<13, 0>
<04, 20>
<03, 35>
}
#declare Hypertrop_1 =
union {
sphere {
<0, 74, 0>, 16
}
sor {
4,
<10, 40>
<10, 42>
<14, 66>
<19, 75>
}
torus {
10, 8
scale <1, 7/8, 1>
translate <0, 35, 0>
}
torus {
4, 6
scale <1, 8/6, 1>
translate <0, 28, 0>
}
}
#declare Hypertrop_Neg =
union {
object {
Hypertrop_1
}
object {
Hypertrop_Projektor_Aussen
}
}
#declare Hypertrop =
union {
object {
Hypertrop_1
}
difference {
object {
Hypertrop_Projektor_Aussen
}
sor {
4,
<21, -7>
<12.9, -0.01>
<03, 20>
<02, 40>
texture { T_BlackMetal }
}
}
sphere {
<0, 0, 0>, 1
scale <3, 23, 3>
translate <0, 20, 0>
texture { T_BlackMetal }
}
texture { pigment { color White } }
}

35
pr/star/Makefile Normal file
View File

@ -0,0 +1,35 @@
# what's where?
POVHOME=/usr/local/povray3
POVBIN=$(POVHOME)/bin
POVINC=$(POVHOME)/include
POVRAY=$(POVBIN)/x-povray
# image
WIDTH=400
HEIGHT=300
all: \
test-hyperfunk.ppm \
test-hypertrop.ppm \
test-hangars.ppm \
test-star.ppm \
test-strut.ppm \
test-winebottle-glass.ppm \
gravojet1.ppm \
totale.ppm \
%.ppm: %.pov
$(POVRAY) +W$(WIDTH) +H$(HEIGHT) +V -I$< +L$(POVINC) +D +FP
%.pov: make%
$< > $@
test-star.ppm: test-star.pov star.pov ynkelonium_texture.pov strut.pov \
Hangar_Schotts.pov T_BlackMetal.pov
test-strut.ppm: test-strut.pov strut.pov
test-hangars.ppm: test-hangars.pov Hangar_Schotts.pov ynkelonium_texture.pov
test-hypertrop.ppm: test-hypertrop.pov Hypertrop.pov \
ynkelonium_texture.pov T_BlackMetal.pov
test-hyperfunk.ppm: test-hyperfunk.pov Hyperfunk.pov \
T_BlackMetal.pov

5
pr/star/TODO Normal file
View File

@ -0,0 +1,5 @@
Antennen am oberen Pol
Geschütze
Traktorstrahler bei unteren Schleusen
Farben!

7
pr/star/T_BlackMetal.pov Normal file
View File

@ -0,0 +1,7 @@
#declare T_BlackMetal =
texture {
pigment {
color rgb <0.1, 0.1, 0.1>
}
finish { F_MetalC }
}

23
pr/star/gravojet1.pov Normal file
View File

@ -0,0 +1,23 @@
#include "colors.inc"
#include "shapes.inc"
#include "textures.inc"
#include "metals.inc"
#include "stones.inc"
global_settings {
assumed_gamma 1.0
ambient_light rgb<0.5, 0.5, 0.5>
}
light_source {
<-200, 200, -200>
color White
}
camera {
location <-70, 120, -71>
look_at <-80, 110, -60>
}
#include "star.pov"
object { star }

6
pr/star/povray.ini Normal file
View File

@ -0,0 +1,6 @@
+A
+HTP
+fp +w400 +h300 +d1
+l/usr/local/povray3/include
+l/home/hjp/wrk/dgk
display_gamma = 2.2

510
pr/star/star.pov Normal file
View File

@ -0,0 +1,510 @@
#include "colors.inc"
#include "shapes.inc"
#include "textures.inc"
#include "metals.inc"
#include "glass.inc"
#include "ynkelonium_texture.pov"
#include "T_BlackMetal.pov"
#include "Hypertrop.pov"
#declare Hull =
difference {
union {
difference {
sphere { <0,0,0>, 100
}
cone {
<0, -10, 0>, 101,
<0, +10, 0>, 101
}
}
union {
torus {
98.5, 1
}
cone {
<0, -1, 0>, 98.5
<0, 1, 0>, 98.5
}
translate <0, -10, 0>
}
union {
torus {
98.5, 1
}
cone {
<0, -1, 0>, 98.5
<0, 1, 0>, 98.5
}
translate <0, +10, 0>
}
}
// obere Hangars
#declare i = 0
#while (i < 360)
superellipsoid {
<0.25, 0.25>
scale <17, 8.5, 25>
translate <0, 41.5, 80>
rotate <0, i, 0>
}
#declare i = i + 45
#end
// untere Hangars
#declare i = 0
#while (i < 360)
superellipsoid {
<0.25, 0.25>
scale <10, 5, 25>
translate <0, -64, 65>
rotate <0, i, 0>
}
#declare i = i + 45
#end
object {
Hypertrop_Neg
translate <0, -100, 0>
}
texture {
Ynkelonium_Texture
}
}
#include "Hangar_Schotts.pov"
#declare Urwa =
difference {
intersection {
cone {
<-6, 0, 22>, 24
<+6, 0, 22>, 24
texture { pigment { color White }}
}
box {
<-5.99, -11, -2>
< 5.99, 11, 10>
texture { pigment { color Blue }}
}
}
#declare i = 0
#while (i < 5)
prism {
conic_sweep
linear_spline
0.5 1
5
<-3, -0.5>, <-0.5, -0.5>, <-0.5, 0.5>, <-3, 0.5>, <-3, -0.5>
scale <1, 4, 1>
rotate <-90, 0, 0>
translate <0, i * 1.5 - 6, 2>
texture { pigment { color Red }}
}
prism {
conic_sweep
linear_spline
0.5 1
5
<5, -0.5>, <0.5, -0.5>, <0.5, 0.5>, <5, 0.5>, <5, -0.5>
scale <1, 4, 1>
rotate <-90, 0, 0>
translate <0, i * 1.5 - 6, 2>
texture { pigment { color Green }}
}
#declare i = i + 1
#end
}
#declare Vhs_pol =
blob {
threshold 0.65
cylinder {
<0, -8, 0>, <0, 8, 0>, 2.5, 1
}
cylinder {
<0, -3, -1>, <0, 5, 0>, 2.5, 1
}
cylinder {
<0, -3, -2>, <0, -3, 0>, 2.5, 1
}
texture { pigment { color White }}
}
#declare Vhs =
union {
object {
Vhs_pol
scale <1, 1, 2>
translate <-7.5, 0, 0>
}
object {
Vhs_pol
scale <1, 1, 3>
translate <-2.5, 0, 0>
}
object {
Vhs_pol
scale <1, 1, 3>
translate <2.5, 0, 0>
}
object {
Vhs_pol
scale <1, 1, 2>
translate <7.5, 0, 0>
}
box {
<-12, -10, 0>, <12, 10, 1>
texture { pigment { color 0.2 * White }}
}
}
#declare Prallfeldprojektor =
union {
superellipsoid {
<0.25, 0.25>
scale <2, 8, 4>
translate <-10, 0, 0>
texture { pigment { color Yellow }}
}
superellipsoid {
<0.25, 0.25>
scale <2, 8, 4>
translate <10, 0, 0>
texture { pigment { color Yellow }}
}
superellipsoid {
<0.25, 0.25>
scale <6, 8, 4>
translate <0, 0, 0>
texture { pigment { color Yellow }}
}
cone {
<-10, 6, -2>, 2
< 10, 6, -2>, 2
texture { T_BlackMetal }
}
cone {
<-10, 2, -2>, 2
< 10, 2, -2>, 2
texture { T_BlackMetal }
}
cone {
<-10, -2, -2>, 2
< 10, -2, -2>, 2
texture { T_BlackMetal }
}
cone {
<-10, -6, -2>, 2
< 10, -6, -2>, 2
texture { T_BlackMetal }
}
}
#declare GJ1 =
union {
cone {
<0, 0, 4>, 4,
<0, 6, 4>, 4
texture { pigment { color Green }}
}
cone {
<-4, 2, 1>, 1
<+4, 2, 1>, 1
}
difference {
cone {
<0, 2, -2>, 2
<0, 2, 2>, 1
}
cone {
<0, 2, -2.01>, 1.95
<0, 2, 2>, 0.90
}
}
sphere {
<0, 2, -1>, 1.4
}
texture { pigment { color 1 * White }}
}
#declare GJ2 =
union {
difference {
box {
<-12, 4, 0.01>, <12, 8, 4>
}
cone {
<-10, 4, 0>, 2
<-10, 4, 4>, 2
}
cone {
<+10, 4, 0>, 2
<+10, 4, 4>, 2
}
box {
<-10, 2, 0>, <10, 6, 4>
}
}
box {
<-12, 8, 0.01>, <12, 10, 4>
texture { T_BlackMetal}
}
texture { pigment { color 1 * Yellow }}
}
#declare GJ3 =
union {
difference {
cone {
<0, 10, 2>, 2
<0, 20, -3.0>, 3.6
texture { T_Winebottle_Glass }
}
cone {
<0, 10, 2>, 1.7
<0, 20.1, -3.0>, 3.4
texture { T_Winebottle_Glass }
}
cone {
<-4, 22, -10>, 10
< 4, 22, -10>, 10
texture { pigment { color 1 * Blue }}
}
}
sphere {
<0, 0, 0>, 1
scale <2, 1, 2>
translate <2, 14, -4>
texture { pigment { color 1 * Yellow }}
}
sphere {
<0, 0, 0>, 1
scale <2, 1, 2>
translate <-2, 14, -4>
texture { pigment { color 1 * Yellow }}
}
sphere {
<0, 0, 0>, 1
scale <1, 2, 1>
rotate <-26.5, 0, 0>
translate <0, 15, -0.5>
texture { pigment { color 1 * Yellow }}
}
}
#declare Gravojet =
union {
// box {
// <-12, 3, 0>, <12, 20, 4>
// texture { pigment { color 0.2 * White }}
// }
object {
GJ1
translate <-8, 0, 0>
}
object {
GJ1
translate < 0, 0, 0>
}
object {
GJ1
translate <+8, 0, 0>
}
object {
GJ2
}
object {
GJ3
}
}
#declare Paratron =
union {
superellipsoid {
<0.5, 0.1>
scale <6, 3, 0.5>
texture { pigment { color 1 * Yellow }}
}
cone {
<-3, 0, -2>,2,
<-3, 0, 2>,2
texture { T_BlackMetal }
}
cone {
<+3, 0, -2>,2,
<+3, 0, 2>,2
texture { T_BlackMetal }
}
}
#declare Strut_Ext = 1
#include "strut.pov"
#include "Hyperfunk.pov"
#declare star =
union {
object {
Hull
}
#declare i = 0
#while (i < 360)
object {
Urwa
translate <0, 0, -100>
rotate <0, i, 0>
}
#declare i = i + 20
#end
#declare i = 10
#while (i < 360)
object {
Vhs
translate <0, 0, -95>
rotate <0, i, 0>
}
#declare i = i + 60
#end
#declare i = 30
#while (i < 360)
object {
Prallfeldprojektor
translate <0, 0, -95>
rotate <0, i, 0>
}
#declare i = i + 60
#end
#declare i = 50
#while (i < 360)
object {
Gravojet
translate <0, -10, -100>
rotate <0, i, 0>
}
#declare i = i + 60
#end
#declare i = 0
#while (i < 360)
object {
Paratron
translate <0, 0, -100>
rotate <13.6, 0, 0>
rotate <0, i, 0>
}
object {
Paratron
translate <0, 0, -100>
rotate <-13.6, 0, 0>
rotate <0, i, 0>
}
#declare i = i + 20
#end
#declare i = 0
#while (i < 360)
object {
Strut
translate <0, -96, 34>
rotate <0, i, 0>
}
#declare i = i + 60
#end
object {
Hangar_Schotts
}
object {
Hypertrop
translate <0, -100, 0>
}
union {
difference {
cone {
<0, -90, 25>, 3
<0, -105, 25>, 3
}
cone {
<0, -90, 25>, 2.8
<0, -105, 25>, 2.8
}
texture {
Ynkelonium_Texture
}
}
cone {
<0, -109.5, 25>, 3
<0, -109.7, 25>, 3
texture {
Ynkelonium_Texture
}
}
cone {
<0, -105.0, 25+2.9>, 0.1
<0, -109.5, 25+2.9>, 0.1
texture { pigment { color Yellow }}
}
cone {
<0, -105.0, 25-2.9>, 0.1
<0, -109.5, 25-2.9>, 0.1
texture { pigment { color Yellow }}
}
cone {
<-2.9, -105.0, 25>, 0.1
<-2.9, -109.5, 25>, 0.1
texture { pigment { color Yellow }}
}
cone {
<+2.9, -105.0, 25>, 0.1
<+2.9, -109.5, 25>, 0.1
texture { pigment { color Yellow }}
}
}
object {
Hyperfunk
translate <0, 100, 0>
}
union {
sphere {
<0, 0, 0>, 1
texture { pigment { color Yellow }}
scale <1, 2, 0.5>
translate <0, 92, 40>
}
sphere {
<0, 0, 0>, 1
texture { pigment { color Yellow }}
scale <1, 2, 0.5>
translate <0, 92, 40>
rotate <0, 120, 0>
}
sphere {
<0, 0, 0>, 1
texture { pigment { color Yellow }}
scale <1, 2, 0.5>
translate <0, 92, 40>
rotate <0, -120, 0>
}
}
translate <0, 110, 0>
}

114
pr/star/strut.pov Normal file
View File

@ -0,0 +1,114 @@
// Landing Strut in normal position:
#include "ynkelonium_texture.pov"
#declare Half_Sphere =
intersection {
sphere { <0, 0, 0>, 1}
plane { <0, -1, 0>, 0}
bounded_by { box {<-1, 0, -1>, <1, 1, 1>}}
}
#declare Strut =
union {
object {
Half_Sphere
scale 4.5
translate <0, 12, 0>
}
cone {
<0, 12, 0>, 4.5
<0, 0, 0>, 4.5
}
superellipsoid {
<1, 0.25>
rotate <90, 0, 0>
scale <6.2, 0.95, 6.2>
translate <0, -0.95, 0>
}
#declare Strut_Y_Off = -1.9 + 8.2 * (1 - Strut_Ext)
cone {
<0, 0, 0>, 2.8,
<0, -4.2, 0>, 2.8
translate <0, Strut_Y_Off, 0>
}
#declare Strut_i = 0
#while (Strut_i < 360)
cone {
<0, -4.2, 2.4>, 0.3
<0, -4.5, 2.4>, 0.25
rotate <0, Strut_i, 0>
translate <0, Strut_Y_Off, 0>
texture {pigment {color White*0.5}}
}
#declare Strut_i = Strut_i + 72
#end
#declare Strut_Y_Off = Strut_Y_Off - 4.2 + 1.3 * (1 - Strut_Ext)
cone {
<0, 0, 0>, 2.1,
<0, -1.9, 0>, 2.1
translate <0, Strut_Y_Off, 0>
}
#declare Strut_Y_Off = Strut_Y_Off - 1.9
#declare Strut_i = 0
#while (Strut_i < 360)
cone {
<0, 1.6, 2.4>, 0.2
<0, 0.3, 2.4>, 0.2
rotate <0, Strut_i, 0>
translate <0, Strut_Y_Off, 0>
texture {pigment {color White*0.5}}
}
cone {
<0, 0.3, 2.4>, 0.25
<0, 0, 2.4>, 0.3
rotate <0, Strut_i, 0>
translate <0, Strut_Y_Off, 0>
texture {pigment {color White*0.5}}
}
#declare Strut_i = Strut_i + 72
#end
cone {
<0, 0, 0>, 2.7
<0, -1.9, 0>, 1.9
translate <0, Strut_Y_Off, 0>
}
#declare Strut_Y_Off = Strut_Y_Off - 1.9 - 1.5
object {
Half_Sphere
scale 2.0
translate <0, Strut_Y_Off, 0>
texture {pigment {color White*0.25}}
}
#declare Strut_i = 0
#while (Strut_i < 360)
cone {
<-0.5, 0, 2.7>, 1.5
< 0.5, 0, 2.7>, 1.5
rotate <0, Strut_i, 0>
translate <0, Strut_Y_Off, 0>
texture {pigment {color White*0.5}}
}
#declare Strut_i = Strut_i + 90
#end
superellipsoid {
<1, 0.25>
rotate <90, 0, 0>
scale <6.2, 1.1, 6.2>
translate <0, Strut_Y_Off-1.1, 0>
}
#declare Strut_Y_Off = Strut_Y_Off - 2.2
#declare Strut_i = 0
#while (Strut_i < 360)
superellipsoid {
<0.25, 0.25>
scale < 1.3, 0.2, 1.3>
translate <0, 0, 5.1>
rotate <0, Strut_i, 0>
translate <0, Strut_Y_Off, 0>
texture {pigment {color White}}
}
#declare Strut_i = Strut_i + 36
#end
texture {Ynkelonium_Texture}
}

31
pr/star/test-hangars.pov Normal file
View File

@ -0,0 +1,31 @@
#include "colors.inc"
#include "shapes.inc"
#include "textures.inc"
#include "metals.inc"
#include "stones.inc"
global_settings {
assumed_gamma 1.0
ambient_light rgb<0.5, 0.5, 0.5>
}
light_source {
<-200, 200, -200>
color White
}
camera {
location <-160, 41, -20>
look_at <-0, 41, -0>
}
#include "Hangar_Schotts.pov"
object { Hangar_Schotts }
//plane {
// <0, 1, 0>, 0.3
// pigment {
// checker color White*0.7, color White*0.5
// }
//}

40
pr/star/test-hyperfunk.pov Normal file
View File

@ -0,0 +1,40 @@
#include "colors.inc"
#include "shapes.inc"
#include "textures.inc"
#include "metals.inc"
#include "stones.inc"
#include "T_BlackMetal.pov"
global_settings {
assumed_gamma 1.0
ambient_light rgb<0.5, 0.5, 0.5>
}
background { color rgb<0.2, 0.4, 0.8> }
light_source {
<-200, 200, -200>
color White
}
light_source {
<0, 0, -10>
color White
}
camera {
location <-0, 1.8, -15>
look_at <-0, 5, -0>
}
#include "Hyperfunk.pov"
object {
Hyperfunk
translate <0, 0, 0>
}
plane {
<0, 1, 0>, 0.3
pigment {
checker color White*0.7, color White*0.5
}
}

35
pr/star/test-hypertrop.pov Normal file
View File

@ -0,0 +1,35 @@
#include "colors.inc"
#include "shapes.inc"
#include "textures.inc"
#include "metals.inc"
#include "stones.inc"
global_settings {
assumed_gamma 1.0
ambient_light rgb<0.5, 0.5, 0.5>
}
light_source {
<-200, 200, -200>
color White
}
light_source {
<0, 0, -10>
color White
}
camera {
location <-20, -3, -20>
look_at <-0, 0, -0>
}
#include "Hypertrop.pov"
object { Hypertrop }
//plane {
// <0, 1, 0>, 0.3
// pigment {
// checker color White*0.7, color White*0.5
// }
//}

31
pr/star/test-star.pov Normal file
View File

@ -0,0 +1,31 @@
#include "colors.inc"
#include "shapes.inc"
#include "textures.inc"
#include "metals.inc"
#include "stones.inc"
global_settings {
assumed_gamma 1.0
ambient_light rgb<0.5, 0.5, 0.5>
}
light_source {
<-200, 200, -200>
color White
}
camera {
location <-30, 220, -0>
look_at <-0, 200, 40>
}
#include "star.pov"
object { star }
plane {
<0, 1, 0>, 0.3
pigment {
checker color White*0.7, color White*0.5
}
}

38
pr/star/test-strut.pov Normal file
View File

@ -0,0 +1,38 @@
#include "colors.inc"
#include "shapes.inc"
#include "textures.inc"
#include "metals.inc"
#include "stones.inc"
global_settings {
assumed_gamma 1.0
ambient_light rgb<0.5, 0.5, 0.5>
}
light_source {
<-200, 200, -200>
color White
}
camera {
location <0, 0, -40>
look_at <0, 0, 0>
}
#declare Strut_Ext = 0
#include "strut.pov"
object { Strut translate <-15, 0, 0>}
#declare Strut_Ext = 0.5
#include "strut.pov"
object { Strut translate <0, 0, 0>}
#declare Strut_Ext = 1
#include "strut.pov"
object { Strut translate <15, 0, 0>}
plane {
<0, 1, 0>, -13.7
pigment {
checker color White*0.7, color White*0.5
}
}

31
pr/star/test-winebottle-glass.pov Normal file
View File

@ -0,0 +1,31 @@
#include "colors.inc"
#include "shapes.inc"
#include "textures.inc"
#include "metals.inc"
#include "glass.inc"
#include "stones.inc"
global_settings {
assumed_gamma 1.0
ambient_light rgb<0.5, 0.5, 0.5>
}
light_source {
<-200, 200, -200>
color White
}
camera {
location <-7, 4, -7>
look_at <-0, 2, -0>
}
plane {
<0, 1, 0>, 0
pigment {
checker color Red, color Blue
}
}
sphere {
<0, 2, 0>, 1.5
texture {T_Winebottle_Glass}
}

23
pr/star/totale.pov Normal file
View File

@ -0,0 +1,23 @@
#include "colors.inc"
#include "shapes.inc"
#include "textures.inc"
#include "metals.inc"
#include "stones.inc"
global_settings {
assumed_gamma 1.0
ambient_light rgb<0.5, 0.5, 0.5>
}
light_source {
<-200, 200, -200>
color White
}
camera {
location <-170, 120, -171>
look_at <-80, 110, -60>
}
#include "star.pov"
object { star }

5
pr/star/ynkelonium_texture.pov Normal file
View File

@ -0,0 +1,5 @@
#include "metals.inc"
#declare Ynkelonium_Texture =
texture {pigment {color <1, 0.2, 0.6>} finish {F_MetalC}}
// texture {pigment {color Salmon} finish {Metal}}
// texture {pigment {color Salmon}}