added kintradims_hoehe to repository. Found on teal, last modified:

2001-08-27

pr/kintradims_hoehe/GNUmakefile

@@ -0,0 +1,23 @@
+# what's where?
+include GNUmakevars
+
+
+all: \
+	test-kintradims_hoehe.png \
+
+
+%.ppm: %.pov
+	$(POVRAY) +W$(WIDTH) +H$(HEIGHT) +V -I$< +L$(POVINC) +D +FP
+
+%.png: %.pov
+	$(POVRAY) +V -I$< +L$(POVINC) +D +FN
+
+%.pov: make%
+	$< > $@
+
+test-kintradims_hoehe.png: test-kintradims_hoehe.pov \
+    kintradims_hoehe.pov plattform.pov zahnrad.pov torbogen.pov 
+	$(POVRAY) +W800 +H600 +V -I$< +L$(POVINC) +D +FN
+
+%.gif: %.ppm
+	ppmquant 256 $< | ppmtogif > $@

pr/kintradims_hoehe/kintradims_hoehe.pov

@@ -0,0 +1,91 @@
+#include "plattform.pov"
+#include "zahnrad.pov"
+#include "torbogen.pov"
+
+#local pf_dupel = 
+    union {
+	object {
+	    plattform
+	    translate <500, 0, 0>
+	    texture {
+		pigment {
+		    color <0.75, 1, 0>
+		}
+	    }
+	}
+	object {
+	    plattform
+	    translate <-500, 0, 0>
+	    texture {
+		pigment {
+		    color <1, 0.75, 0>
+		}
+	    }
+	}
+    }
+
+#local pf_tripel = 
+    union {
+	object {
+	    plattform
+	    translate <500, 0, 0>
+	    texture {
+		pigment {
+		    color <0.75, 1, 1>
+		}
+	    }
+	}
+	object {
+	    plattform
+	    translate <500, 0, 0>
+	    rotate <0, 120, 0>
+	    texture {
+		pigment {
+		    color <1, 0.75, 1>
+		}
+	    }
+	}
+	object {
+	    plattform
+	    translate <500, 0, 0>
+	    rotate <0, -120, 0>
+	    texture {
+		pigment {
+		    color <1, 1, 0.75>
+		}
+	    }
+	}
+    }
+#declare kintradims_hoehe =
+    union {
+	object {
+	    pf_dupel
+	}
+	object {
+	    pf_tripel
+	    translate <0, 180, 0>
+	    rotate <0, 45, 0>
+	}
+	object {
+	    pf_dupel
+	    translate <0, 360, 0>
+	    rotate <0, 90, 0>
+	}
+	object {
+	    pf_tripel
+	    translate <0, 540, 0>
+	    rotate <0, 135, 0>
+	}
+	object {
+	    pf_dupel
+	    translate <0, 720, 0>
+	}
+	object {
+	    zahnrad
+	    translate <-500, 900, 0>
+	}
+	object {
+	    torbogen
+	    translate <+500, 900, 0>
+	}
+    }

pr/kintradims_hoehe/plattform.pov

@@ -0,0 +1,37 @@
+#declare Eps = 1E-6;
+
+#declare plattform = 
+    union {
+	difference {
+	    cylinder {
+		<0, 0, 0> <0, 180, 0> 1550/2
+	    }
+	    difference {
+		cylinder {
+		<0, 18, 0> <0, 162, 0> 1550/2+Eps
+		}
+		cylinder {
+		<0, 18, 0> <0, 162, 0> 1550/2-18
+		}
+	    }
+	    #local i = 0; 
+	    #while (i < 27) 
+		cylinder {
+		    <0, 90, 1550/2-200> <0, 90, 1550/2+Eps>, 72
+		    rotate <0, i * 360 / 27, 0>
+		}
+		#local i = i + 1;
+	    #end
+	}
+	#local i = 0; 
+	#while (i < 27) 
+	    cylinder {
+		<0, 18, 1550/2-18> <0, 162, 1550/2-18>, 18
+		rotate <0, (i + 0.5) * 360 / 27, 0>
+	    }
+	    #local i = i + 1;
+	#end
+	cylinder {
+	    <0, 89, 0> <0, 91, 0> 1550/2
+	}
+    }

pr/kintradims_hoehe/povray.ini

@@ -0,0 +1,6 @@
++MB5
++QR
++A
++HTN
++fp +w640 +h480 +d1 
+display_gamma = 2.2

pr/kintradims_hoehe/test-kintradims_hoehe.pov

@@ -0,0 +1,79 @@
+#include "colors.inc"
+#include "shapes.inc"
+#include "textures.inc"
+#include "metals.inc"
+#include "stones.inc"
+
+#declare SCHNITT_1 = 1;	// Quadrant -/*/-
+
+global_settings {
+        assumed_gamma 1.0
+        ambient_light rgb<0.5, 0.5, 0.5>
+}
+background { color rgb<0.2, 0.4, 0.8>  }
+light_source {
+    <-20000, 20000, -20000>
+    color White
+}
+
+#local CP = <-3000, +1500, -1000>;
+light_source {
+    CP
+    color White*0.5
+}
+//camera {
+//	location CP
+//	look_at <-0, -0, -0>
+//	orthographic
+//	up <0, 4000, 0>
+//	right <8000, 0, 0>
+//}
+camera {
+        location CP
+        look_at <-0, 900, -0>
+}
+
+#include "kintradims_hoehe.pov"
+
+    object {
+	kintradims_hoehe
+    }
+
+#declare gatter =
+    union {
+	#local I = -50;
+	#while (I <= 50) 
+	    #switch (mod(I, 10) )
+	    #case (0)
+		#local Color = color <0, 1, 0>;
+		#local R = 0.2;
+		#break;
+	    #case (5)
+	    #case (-5)
+		#local Color = color <1, 0, 0>;
+		#local R = 0.15;
+		#break;
+	    #else 
+		#local Color = color <0, 0, 1>;
+		#local R = 0.1;
+	    #end
+		    
+	    cylinder {
+		<I, -50, 0>, <I, +50, 0> R
+		texture {pigment { color Color } }
+	    }
+	    cylinder {
+		<-50, I, 0>, <+50, I, 0> R
+		texture {pigment { color Color } }
+	    }
+	    #local I = I + 1;
+	#end
+
+    }
+
+object {
+    gatter 
+    rotate <90, 0, 0>
+    scale 100
+}
+

pr/kintradims_hoehe/torbogen.pov

@@ -0,0 +1,32 @@
+#local P1 = 0.3;
+#local P2 = 0.6;
+
+#declare torbogen =
+    union {
+	prism {
+	    bezier_spline 
+	    -125, 125,
+	    24
+	    <-450, 0> <-450*P2, 720> <-450*P1, 720> <0, 720>
+	    <0, 720> <450*P1, 720> <450*P2, 720> <450, 0>
+	    <450, 0> <420, 0> <390, 0> <360, 0>
+	    <360, 0> <360*P2, 570> <360*P1, 570> <0, 570>
+	    <0, 570> <-360*P1, 570> <-360*P2, 570>, <-360, 0>
+	    <-360, 0> <-390, 0> <-420, 0> <-450, 0>
+	    texture {
+		pigment {
+		    color <0.7, 0.7, 0.75>
+		}
+	    }
+	    rotate <-90, 0, 0>
+	    rotate <0, 90, 0>
+	}
+	sphere {
+	    <0, 570/2, 0> 350/2
+	    texture {
+		pigment {
+		    color <1, 1, 1.5>
+		}
+	    }
+	}
+    }

pr/kintradims_hoehe/zahnrad.pov

@@ -0,0 +1,29 @@
+#local R = 350;
+#local X1 = 90;
+#local Z1 = sqrt(R^2-X1^2);
+#local S = 220;
+#local Z2 = Z1 + sqrt(S^2-X1^2);
+
+#declare zahnrad = 
+    union {
+	cylinder {
+	    <0, 0, 0> <0, 180, 0> R
+	}
+
+	#local a = 0;
+	#while (a < 360) 
+	    prism {
+		0, 180,
+		4
+		<X1, Z1>, <0, Z2>, <-X1, Z1>, <X1, Z1>
+		rotate <0, a, 0>
+	    }
+	    #local a = a + 45;
+	#end
+	
+	texture {
+	    pigment {
+		color <0.75, 0.75, 0.75>
+	    }
+	}
+    }