#include "colors.inc"
#include "shapes.inc"
#include "textures.inc"
#include "metals.inc"
#include "stones.inc"

global_settings {
        assumed_gamma 1.0
        ambient_light rgb<0.5, 0.5, 0.5>
}
background { color rgb<0.2, 0.4, 0.8>  }


// sonne
light_source {
    <149E9*100, 0, 0>
    color White
    rotate <0, 0, 60>
    rotate <0, 30, 0>
}

// Lampen
#declare i = -450;
#while (i <= 450) 
    #declare j = -500;
    #while (j <= 500) 
	light_source {
	    <i, 295, j>
	    color White
	    area_light <-40, 0, -90> <40, 0, 90> 5, 5
	    adaptive 1
	    jitter
	}
    	#declare j = j + 200;
    #end
    #declare i = i + 100;
#end



camera {
        location <9, 170, -550>
        look_at <0, 90, 0>
	//angle 30
}

#include "laires_auge.pov"

object {
    laires_auge
    rotate <0, 0, 90>
    translate <0, 90 + 1.1, 0>
}


// Zimmer
difference {
    box {
	<-520, -20, -620>
	<520, 320, 620>
	pigment {
	    color White
	}
    }
    box {
	<-500, 0, -600>
	<500, 300, 600>
	pigment {
	    color White
	}
    }

    // Fenster
    #declare i = -6;
    #while (i < 6) 
	box {
	    <499, 100, i*100+10>
	    <521, 280, i*100+90>
	    pigment {
		color White
	    }
	}
	#declare i = i + 1;
    #end

    // Tür
    box {
	<-499, 0, 100+10>
	<-521, 200, 100+90>
	pigment {
	    color White
	}
    }
}


// Tisch

#declare tischbein = 
    box {
	<-1,  0, -1>
	<+1, 88, +1>
	texture { T_Chrome_5C }
    }

union {
    box {
	<-50, 88, -100>
	< 50, 90,  100>
	texture { T_Stone9 }
    }
    object {
	tischbein
	translate <-49, 0, -99>
    }
    object {
	tischbein
	translate <-49, 0, +99>
    }
    object {
	tischbein
	translate <+49, 0, +99>
    }
    object {
	tischbein
	translate <+49, 0, -99>
    }
}

plane {
    <0, 1, 0>, -1
    pigment { color Green }
}

