#include "polgeschuetz.pov"

#declare deck_20 = 
    union {
	intersection {
	    union {
		#if (HUELLE)
		difference {
		    object {
			huelle
			texture {
			    pigment {
				color rgbf <0.5, 0.5, 0.7, 0.7>
			    }
			}
		    }
		    cylinder {
			<0, 45, 0> <0, 51, 0> 5.001
		    }
		}
		#end
		difference {
		    intersection {
			sphere {
			    <0, 0, 0> 50
			}
			cylinder {
			    <0, 45, 0> <0, 51, 0> 5.5
			}
		    }
		    sphere {
			<0, 0, 0> 48
		    }
		    cylinder {
			<0, 45, 0> <0, 51, 0> 5
		    }
		    #ifdef (SCHNITT_1)
		    box {
			<-50,   45, -50>
			< -0.1, 50,  -0.1>
		    }
		    #end
		    texture { T_arkonstahl }
		}
	    }
	    box {
		<-50, 45, -50>
		< 50, 50,  50>
	    }
	}
	difference {
	    cone {
		<0, 44.8, 0> 20
		<0, 45.2, 0> 18
		texture { T_arkonstahl }
	    }
	    #ifdef (SCHNITT_1)
		box {
		    <-50,   44, -50>
		    < -0.1, 50,  -0.1>
		}
	    #end
	}
	object {
	    polgeschuetz
	}
	light_source {
	    <0, 47.6, -6>
	    color <0.8, 0.8, 0.6>
	}
    }
