/* einfaches Menschenmodell. 
 *
 * Wenig Details, weil ich viele davon brauche
 */
#declare Mensch =
    union {
	// Kopf
	union {
	    sphere {
		<0, 0, 0>, 1
		scale <0.1, 0.125, 0.125>

	    }
	    intersection {
		cone {
		    <0, 0, 0> 1
		    <0, -1, 0> 1
		}
		box {
		    <-1, -1, 0>
		    <+1, 0, 1>
		}
		cone {
		    <0, 0, -1> 1
		    <0, 0, +1> 1
		}
		scale <0.1, 0.125, 0.125>
	    }
	    cone {
		<0, 0, 0> 0.05
		<0, -0.5, 0> 0.05
	    }
	    texture { pigment { color Flesh } }
	    translate <0, 1.625, 0>
	}

	// Körper
	union {
	    cone {
		<0, 0.05, 0>, 0.05
		<0, 0, 0>, 0.25
		scale <1, 1, 0.5>
	    }
	    cone {
		<0, 0, 0>, 0.25
		<0, -0.55, 0>, 0
		scale <1, 1, 0.5>
	    }
	    texture { pigment { color Mensch_Farbe_Jacke } }
	    translate <0, 1.4, 0>
	}

	// Becken
	sphere {
	    <0, 0, 0> 1
	    scale <0.15, 0.15, 0.1>
	    translate <0, 1, 0>
	    texture { pigment { color Mensch_Farbe_Hose } }
	}

	// Beine
	cone {
	    <0.1, -1, 0>, 0.05
	    <0.07, 0, 0>, 0.07
	    texture { pigment { color Mensch_Farbe_Hose } }
	    rotate <Mensch_Schritt, 0, 0>
	    translate <0, 1, 0>
	}
	cone {
	    <-0.1, -1, 0>, 0.05
	    <-0.07, 0, 0>, 0.07
	    texture { pigment { color Mensch_Farbe_Hose } }
	    rotate <-Mensch_Schritt, 0, 0>
	    translate <0, 1, 0>
	}

	// Arme
	union {
	    cone {
		<0.0, -0.6, 0>, 0.05
		<0.0, 0.0, 0>, 0.05
		texture { pigment { color Mensch_Farbe_Jacke } }
	    }
	    sphere {
		<0.0, -0.64, 0>, 0.04
		texture { pigment { color Flesh } }
	    }
	    rotate <-Mensch_Schritt, 0, 0>
	    translate <0.20, 1.4, 0>
	}
	union {
	    cone {
		<0.0, -0.6, 0>, 0.05
		<0.0, 0.0, 0>, 0.05
		texture { pigment { color Mensch_Farbe_Jacke } }
	    }
	    sphere {
		<0.0, -0.64, 0>, 0.04
		texture { pigment { color Flesh } }
	    }
	    rotate <Mensch_Schritt, 0, 0>
	    translate <-0.20, 1.4, 0>
	}
    }

