#include "ynkelonium_texture.pov"

#declare Hangar_Schotts =
intersection {
    difference {
	sphere {
	    <0,0,0>, 99
	}
	sphere {
	    <0,0,0>, 98
	}
    }

    union {
	// obere Hangars

	#declare i = 0
	#while (i < 360) 
	    difference {
		superellipsoid {
		    <0.25, 0.25>
		    scale <17, 8.5, 25>
		}
		box {
		    <-0.1, -8.5, -25>
		    <+0.1, +8.5, +25>
		}
		translate <0, 41.5, 80>
		rotate <0, i, 0>
	    }
	    #declare i = i + 45
	#end

	// Mannschleusen

	#declare i = 0
	#while (i < 360) 
	    superellipsoid {
		<0.25, 0.25>
		scale <4, 2, 4>
		translate <0, -40, 92>
		rotate <0, i, 0>
	    }
	    #declare i = i + 45
	#end

	// untere Hangars

	#declare i = 0
	#while (i < 360) 
	    difference {
		superellipsoid {
		    <0.25, 0.25>
		    scale <10, 5, 25>
		}
		box {
		    <-10, -0.1, -25>
		    <+10, +0.1, +25>
		}
		translate <0, -64, 65>
		rotate <0, i, 0>
	    }
	    #declare i = i + 45
	#end
    }

    texture { Ynkelonium_Texture }
}


